(define-module (parsee)
  #:use-module (guix packages)
  #:use-module (guix git-download)
  #:use-module (guix build-system gnu)
  #:use-module (guix gexp)
  #:use-module (guix utils)
  #:use-module (gnu packages tls)
  #:use-module (gnu packages databases)
  #:use-module ((guix licenses) #:prefix license:))

(define vcs-file?
  (or (git-predicate
       (dirname (dirname (current-source-directory))))
      (const #t)))

(define-public cytoplasm
  (let ((commit "32f31fe6d61583630995d956ed7bd7566c4dc14f")
        (revision "0"))
    (package
      (name "cytoplasm")
      (version (git-version "0.4.1" revision commit))
      (source
       (origin
         (method git-fetch)
         (uri (git-reference
               (url "https://git.telodendria.io/Telodendria/Cytoplasm")
               (commit commit)))
         (file-name (git-file-name name version))
         (sha256
          (base32 "09x5xfswryf3wjs1synh972yr2fmpjmffi7pjyjdzb4asqh4whrv"))))
      (build-system gnu-build-system)
      (arguments
       (list
        #:tests? #f
        #:configure-flags #~'("--with-lmdb")
        #:phases #~(modify-phases %standard-phases
                     (add-before 'configure 'add-ld-flags
                       (lambda _
                         (substitute* "./configure"
                           (("(LDFLAGS=\"\\$\\{LIBS\\} \\$\\{LDFLAGS\\})\"" all flags)
                            (string-append flags " -Wl,-rpath=" #$output "/lib\"")))
                         (mkdir-p (string-append #$output "/lib"))))
                     (replace 'configure
                       (lambda* (#:key configure-flags #:allow-other-keys)
                         (apply invoke `("./configure"
                                         ,(string-append "--prefix=" #$output)
                                         ,@configure-flags)))))))
      (inputs (list openssl lmdb))
      (home-page "https://git.telodendria.io/Telodendria/Cytoplasm")
      (synopsis "General-purpose high-level networked C library")
      (description "Cytoplasm is a general-purpose C library for creating
high-level (particularly networked and multi-threaded) C applications.")
      (license license:expat))))

(define-public parsee
  (package
    (name "parsee")
    (version "0.0.1-git")
    (source
     (local-file "../.." "parsee-checkout"
                 #:recursive? #t
                 #:select? vcs-file?))
    (build-system gnu-build-system)
    (arguments
     (list
      #:tests? #f
      #:make-flags #~(list "CC=gcc"
                           (string-append "CYTO_INC=" #$cytoplasm "/include")
                           (string-append "CYTO_LIB=" #$cytoplasm "/lib")
                           (string-append "PREFIX=" #$output))
      #:phases #~(modify-phases %standard-phases
                   (replace 'configure
                     (lambda* (#:key inputs #:allow-other-keys)
                       (let ((gcc (string-append (assoc-ref inputs "gcc") "/bin/gcc")))
                         (invoke gcc "configure.c" "-o" "configure")
                         (invoke "./configure")))))))
    (home-page "https://git.kappach.at/lda/Parsee")
    (synopsis "Jealous Matrix to XMPP bridge")
    (description "Parsee is a Matrix-XMPP bridge written in C99 with Cytoplasm.")
    (license license:agpl3+)))

parsee